! Independent Pathway Model
! NL IQ data

#NGroups 4
#define nvar 6
#define nfac 1

G1: Define matrices
 Calculation
 Begin Matrices;
  X full nvar nfac Free     ! common factor genetic path coefficients
  Y full nvar nfac Free     ! common factor shared environment path coefficients
  Z full nvar nfac Free     ! common factor unique environment path coefficients
  T diag nvar nvar Free     ! variable specific genetic path coefficients
  U diag nvar nvar Free     ! variable specific shared env path coefficients
  V diag nvar nvar Free     ! variable specific residual path coefficients
  M full  1 nvar Free       ! means 
 End Matrices;
  Start .6 X 1 1 1 - X 1 nvar 1  Y 1 1 1 - Y 1 nvar 1 Z 1 1 1 - Z 1 nvar 1  
  Start 4 T 1 1 1 - T 1 nvar nvar  U 1 1 1 - U 1 nvar nvar  
  Start 5 V 1 1 1 - V 1 nvar nvar
  Matrix M 90 63 80 90 63 84
 Begin Algebra;
  A= X*X' + T*T';           ! additive genetic variance components
  C= Y*Y' + U*U';           ! shared environment variance components
  E= Z*Z' + V*V';           ! nonshared environment variance components
 End Algebra;
 Option No_Output
End

G2: MZ twins
#include iqnlmz.dat
 Begin Matrices = Group 1;
 Means M | M ; 
 Covariance A+C+E | A+C   _
            A+C   | A+C+E  ;
 Option Rsiduals
End

G3: DZ twins
#include iqnldz.dat
 Begin Matrices= Group 1;
  H full 1 1
 End Matrices;
  Matrix H .5
 Means M | M ;
 Covariance A+C+E | H@A+C _
            H@A+C | A+C+E  ;
 Option Rsiduals 
End

G4: Calculate Standardised Solution
 Calculation
 Matrices = Group 1
  I Iden nvar nvar
 End Matrices;
 Begin Algebra;
  R=A+C+E;                  ! total variance
  S=(\sqrt(I.R))~;          ! diagonal matrix of standard deviations
  P=S*X_ S*Y_ S*Z;          ! standardized estimates for common factors
  Q=S*T_ S*U_ S*V;          ! standardized estimates for specific factors
 End Algebra; 
 Labels Row P a1 a2 a3 a4 a5 a6 c1 c2 c3 c4 c5 c6 e1 e2 e3 e4 e5 e6
 Labels Col P var1 var2 var3 var4 var5 var6
 Labels Row Q as1 as2 as3 as4 as5 as6 cs1 cs2 cs3 cs4 cs5 cs6 es1 es2 es3 es4 es5 es6
 Labels Col Q var1 var2 var3 var4 var5 var6
 Options NDecimals=4
End