! Common Pathway Model
! NL IQ data

#NGroups 5
#define nvar 6
#define nfac 1

G1: Define matrices
 Calculation
 Begin Matrices;
  X full nfac nfac Free     ! latent factor genetic path coefficient
  Y full nfac nfac Free     ! latent factor shared environment path coefficient
  Z full nfac nfac Free     ! latent factor unique environment path coefficient
  T diag nvar nvar Free     ! variable specific genetic path coefficients
  U diag nvar nvar Free     ! variable specific shared env path coefficients
  V diag nvar nvar Free     ! variable specific residual path coefficients
  F full nvar nfac Free     ! loadings of variables on latent factor
  I Iden 2 2 
  M full  1 nvar Free       ! means 
 End Matrices;
  Start 15 F 1 1 1 - F 1 nvar 1
  Start .6 X 1 1 1 Y 1 1 1 Z 1 1 
  Start 4 T 1 1 1 - T 1 nvar nvar  U 1 1 1 - U 1 nvar nvar  V 1 1 1 - V 1 nvar nvar
  Matrix M 90 63 80 90 63 84
 Begin Algebra;
  A= F&(X*X') + T*T';       ! genetic variance components
  C= F&(Y*Y') + U*U';       ! shared environment variance components
  E= F&(Z*Z') + V*V';       ! nonshared environment variance components
  L= X*X' + Y*Y' + Z*Z';    ! variance of latent factor
 End Algebra;
 Option No_Output
End

G2: MZ twins
#include iqnlmz.dat
 Begin Matrices = Group 1;
 Means M | M ;
 Covariance A+C+E | A+C   _
            A+C   | A+C+E  ;
 Option Rsiduals
End

G3: DZ twins
#include iqnldz.dat
 Begin Matrices = Group 1;
  H full 1 1
 End Matrices;
  Matrix H .5
 Means M | M ;
 Covariance A+C+E | H@A+C _
            H@A+C | A+C+E  ;
 Option Rsiduals
End

G4: Constrain variance of latent factor to 1
 Constraint
 Begin Matrices;
  L computed =L1
  I unit 1 1
 End Matrices;
 Constraint L = I ;
End

G5: Calculate Standardised Solution
 Calculation
 Matrices = Group 1
  D Iden nvar nvar
 End Matrices;
 Begin Algebra;
  R=A+C+E;                  ! total variance
  S=(\sqrt(D.R))~;          ! diagonal matrix of standard deviations
  P=S*F;                    ! standardized estimates for loadings latent factor
  Q=S*T_ S*U_ S*V;          ! standardized estimates for specific factors
 End Algebra;
 Label Row P f1 f2 f3 f4 f5 f6
 Label Row Q as1 as2 as3 as4 as5 as6 cs1 cs2 cs3 cs4 cs5 cs6 es1 es2 es3 es4 es5 es6
 Options NDecimals=4
End