! Transmission Models
! US BMI data

#NGroups 4
#define nvar 5
#define nvarm1 4
#define nvarx2 10

G1: female model parameters
Calculation
 Begin Matrices;
  X Diag nvarm1 nvarm1 Free ! additive genetic transmission paths
  Y Diag nvarm1 nvarm1 Free ! common environmental transmission paths
  W Diag nvarm1 nvarm1 Fixed! dominance transmission paths
  Z Diag nvarm1 nvarm1 Free ! unique environmental transmission paths
  I Iden nvar nvar          ! identity matrix
  F Zero nvarm1 1           ! right column of zeros to fill out trans
  U Zero 1 nvar             ! top row of zeros to fill out trans
  O Diag nvar nvar Free     ! genetic specifics
  P Diag nvar nvar Free     ! common environmental specifics
  R Diag nvar nvar Fixed    ! dominance specifics
  T Diag nvar nvar Free     ! specific environmental specifics
  H Full 1 1
  Q Full 1 1
 End Matrices;
  Matrix H .5
  Matrix Q .25
 Begin Algebra;
  G= (I-(U_X|F))~; 
  K= (I-(U_Y|F))~;
  L= (I-(U_Z|F))~;
  J= (I-(U_W|F))~;
  A= G*O*O'*G';
  C= K*P*P'*K';
  E= L*T*T'*L';
  D= J*R*R'*J';
 End Algebra;
  Start .4 All
  Start .5 T 1 1 1 T 1 2 2 T 1 3 3 T 1 4 4 T 1 5 5
  Start 0 X 1 1 1 - X 1 nvarm1 nvarm1  Y 1 1 1 - Y 1 nvarm1 nvarm1 
  Start 0 W 1 1 1 - W 1 nvarm1 nvarm1  Z 1 1 1 - Z 1 nvarm1 nvarm1 
End

G2: MZ twin pairs
#include bmi5mzf.dat
 Begin Matrices =Group 1
  M Full 1 nvarx2 Free
 End Matrices;
  Start 10 M 1 1 to M 1 nvarx2
 Means M ;
 Covariances  (A+C+D+E | A+C+D _
               A+C+D   | A+C+D+E) ;
Option No_Output  
End

G3: DZ twin pairs
#include bmi5dzf.dat
 Begin Matrices =Group 1
  M Full 1 nvarx2 Free
 End Matrices;
  Start 10 M 1 1 to M 1 nvarx2
 Means M ;
 Covariances  (A+C+D+E   | H@A+C+Q@D _
               H@A+C+Q@D | A+C+D+E  ) ;
Option No_Output
End

G4
Calculation
 Matrices = Group 1
  I Iden nvar nvar
 End Matrices;
 Begin Algebra;
  V= A+C+D+E ;
  S= \sqrt(I.(V)) ;
  M= \d2v(S~*O)_ \d2v(S~*P)_ \d2v(S~*R)_ \d2v(S~*T)_
     S~*(U_X|F)_ S~*(U_Y|F)_ S~*(U_W|F)_ S~*(U_Z|F);
 End Algebra;
End