! Estimate genetic and environmental components - ACED model
! OZ BMI data - younger females & males + opposite sex twins

#NGroups 7
#define nvar 1
#define nvar2 2

G1: Parameters
 Calculation 
 Begin Matrices;
  X Lower nvar nvar Free  ! FEMALES additive genetic path, a
  Y Lower nvar nvar       ! FEMALES common environmental path, c
  Z Lower nvar nvar Free  ! FEMALES specific environmental path, e
  W Lower nvar nvar Free  ! FEMALES dominance genetic path, d
  S Lower nvar nvar Free  ! MALES additive genetic path, a
  T Lower nvar nvar       ! MALES common environmental path, c
  U Lower nvar nvar Free  ! MALES specific environmental path, e
  V Lower nvar nvar Free  ! MALES dominance genetic path, d
  H Full 1 1              ! scalar, 0.5
  Q Full 1 1              ! scalar, 0.25
  F Full 1 1 Free         ! free for DZO
 End Matrices;
  Matrix H .5
  Start .5 F 1 1 1
 Begin Algebra;
  A= X*X';                ! FEMALES additive genetic variance
  C= Y*Y';                ! FEMALES common environmental variance
  E= Z*Z';                ! FEMALES unique environmental variance
  D= W*W';                ! FEMALES dominance variance
  K= S*S';                ! MALES additive genetic variance
  L= T*T';                ! MALES common environmental variance
  N= U*U';                ! MALES unique environmental variance
  O= V*V';                ! MALES dominance variance
 End Algebra;
End

Title G2: MZf data
 #include ozbmi.dat
 Select if zyg =1
 Select bmi1 bmi2 ;
 Begin Matrices = Group 1;
  M Full 1 nvar2 Free
 Means M;
 Covariance 
    A+C+E+D | A+C+D   _  
    A+C+D   | A+C+E+D;
 Option RSiduals;
End

Title G3: DZf data
 #include ozbmi.dat
 Select if zyg =3
 Select bmi1 bmi2 ;
 Begin Matrices = Group 1;
  M Full 1 nvar2 Free
 End Matrices;
 Means M;
 Covariance
    A+C+E+D   | H@A+C+Q@D _
    H@A+C+Q@D | A+C+E+D;
 Option RSiduals
End

Title G4: MZm data
 #include ozbmi.dat
 Select if zyg =2
 Select bmi1 bmi2 ;
 Begin Matrices = Group 1;
  M Full 1 nvar2 Free
 Means M;
 Covariance 
    K+L+N+O | K+L+O   _
    K+L+O   | K+L+N+O  ;
 Option RSiduals;
End

Title G5: DZm data
 #include ozbmi.dat
 Select if zyg =4
 Select bmi1 bmi2 ;
 Begin Matrices = Group 1;
  M Full 1 nvar2 Free
 End Matrices;
 Means M;
 Covariance
    K+L+N+O   | H@K+L+Q@O _
    H@K+L+Q@O | K+L+N+O  ;
 Option RSiduals
End

Title G6: DZfm data
 #include ozbmi.dat
 Select if zyg =5
 Select bmi1 bmi2 ;
 Begin Matrices = Group 1;
  M Full 1 nvar2 Free
 End Matrices;
 Means M;
 Covariance
    A+C+E+D   | F@(X*S')+(Y*T')+Q@(W*V') _
    F@(S*X')+(T*Y')+Q@(V*W')  | K+L+N+O  ;
 Option RSiduals
End

Title G7: Standardization
 Calculation
 Begin Matrices = Group 1;
 End Matrices;
  Start .5 all
  Start 20 M 2 1 1 - M 2 1 nvar2
  Start 20 M 3 1 1 - M 3 1 nvar2
  Start 20 M 4 1 1 - M 4 1 nvar2
  Start 20 M 5 1 1 - M 5 1 nvar2
  Start 20 M 6 1 1 - M 6 1 nvar2
 Begin Algebra;
  G= A+C+E+D;             ! FEMALES total variance
  J= K+L+N+O;             ! MALES total variance
  P= A%G| C%G| E%G| D%G_  ! FEMALES FIRST ROW standardized variance components
     K%J| L%J| N%J| O%J;  ! MALES SECOND ROW standardized variance components
 End Algebra;
 Option NDecimals=4
!ADE model
! Option Sat=8310.308, 3633
 Option Multiple Issat
 !Interval @95 P 1 1 1 P 1 1 2 P 1 1 3 P 1 1 4 P 1 2 1 P 1 2 2 P 1 2 3 P 1 2 4
End

! Test for qualitative sex differences (nature of effect difference by sex)
 Drop @.5 F 1 1 1 
End

Save ozbmi5.mxs

! Test for quantitative sex differences (magnitude of effect difference by sex)
 Equate X 1 1 1 S 1 1 1   ! additive genetic factor loadings equal for M&F
 Equate Z 1 1 1 U 1 1 1   ! unique environmental factor loadings equal for M&F
 Equate W 1 1 1 V 1 1 1   ! dominance factor loadings equal for M&F
End