! Estimate genetic and environmental components - ACED model
! US MDD data - females

#NGroups 4
#define nvar 1
#define nvar2 2

Title 1: Model Parameters
 Calculation
 Begin Matrices;
  X Lower nvar nvar Free
  Y Lower nvar nvar 
  Z Lower nvar nvar Free
  W Lower nvar nvar Free
  H Full 1 1
  Q Full 1 1
 End Matrices;
  Matrix H .5
  Matrix Q .25
 Begin Algebra;
  A= X*X';
  C= Y*Y';
  E= Z*Z';
  D= W*W';
 End Algebra;
End Group

Title 2: MZ data
 #include usmdd.dat
 Select if zyg =1
 Select mdd1 mdd2 ;
 Begin Matrices = Group 1;
  T Full 1 nvar2 Free
 End Matrices;
 Thresholds T;
 Covariance 
    A+C+E+D | A+C+D   _  
    A+C+D   | A+C+E+D;
 Option RSiduals;
End

Title 3: DZ data
 #include usmdd.dat
 Select if zyg =2
 Select mdd1 mdd2 ;
 Begin Matrices = Group 1;
  T Full 1 nvar2 Free
 End Matrices;
 Thresholds T;
 Covariance
    A+C+E+D   | H@A+C+Q@D _
    H@A+C+Q@D | A+C+E+D;
 Option RSiduals
End

Title 4: Constrain variances=1
 Constraint
 Begin Matrices = Group 1;
  I Iden 1 1
 End Matrices;
  Start .5 all
  Start 1 T 2 1 1 - T 2 1 nvar2
  Start 1 T 3 1 1 - T 3 1 nvar2
 Begin Algebra;
  P=A|C|E|D;
 End Algebra;
 Constraint A+C+E+D=I;
 Option NDecimals=4
!ADE model
 Option Sat=2508.004,2054
 Option Multiple
End

!AE model
 Drop W 1 1 1
End

!ACE model
 Free Y 1 1 1
End

!CE model
 Drop X 1 1 1
End

!E model
 Drop Y 1 1 1
End