! Bivariate ACE model
! US BMI-Skinfold data - 11 year old females

#NGroups 4
#define nvar 2                         ! N dependent variables per twin
#define nvarx2 4

G1: Model Parameters
Calculation
 Begin matrices;
  X Lower nvar nvar Free               ! additive genetic path coefficient
  Y Lower nvar nvar Free               ! common environmental path coefficient
  Z Lower nvar nvar Free               ! unique environmental path coefficient
  H Full 1 1                           ! 
 End matrices;
  Matrix H .5
  Start .5 X 1 1 1  Y 1 1 1  Z 1 1 1
  Start .7 X 1 2 2  Y 1 2 2  Z 1 2 2
 Begin algebra;
  A= X*X';                             ! additive genetic variance
  C= Y*Y';                             ! common environmental variance
  E= Z*Z';                             ! unique environmental variance
 End Algebra;
End

G2: MZ twins
#include usski.dat
  Select if  zyg =2 ;
  Select t1bic t1tri  t2bic t2tri ;
 Begin Matrices = Group 1;
  M Full 1 nvarx2 Free                 ! means
 End Matrices;
  Matrix M 20 20 20 20
 Means M;
 Covariances
  A+C+E | A+C   _
  A+C   | A+C+E  ;
 Options RSiduals
End

G3: DZ twins
#include usski.dat
  Select if  zyg =4 ;
  Select t1bic t1tri  t2bic t2tri ;
 Begin Matrices = Group 1;
  M Full 1 nvarx2 Free                 ! means
 End Matrices;
  Matrix M 20 20 20 20
 Means M;
 Covariances
  A+C+E | H@A+C _
  H@A+C | A+C+E  ;
 Options RSiduals
End

G4: summary of relevant statistics
Calculation
 Begin Matrices = Group 1
 Begin Algebra ;
  V= A+C+E;                            ! total variance
  S= A%V | C%V | E%V ;                 ! standardized variance components
  R= \stnd(A)| \stnd(C)| \stnd(E);     ! calculates rg|rc|re
 End algebra;
  Labels Row V bic tri
  Labels Row S bic tri
  Labels Row R bic tri
  Labels Column S A1 A2 C1 C2 E1 E2
  Labels Column R A1 A2 C1 C2 E1 E2
  Interval @95 S 1 1 S 1 3 S 1 5       ! CI's A,C,E for first phenotype
  Interval @95 S 2 2 S 2 4 S 2 6       ! CI's A,C,E for second phenotype
  Interval @95 R 2 1 R 2 3 R 2 5       ! CI's rg, rc, re 
 Option Sat= 2732.302,638
End